do_a = "target1:do_b target2:do_b"

在这个例子中，执行任务a之前必须要先执行target1的任务b和target2的任务b。你可以尝试下面的例子：

printhello.bb:

DESCRIPTION = "Prints Hello World"
PN = 'printhello'
PV = '1'

python do_configure() {
    bb.plain("************************");
    bb.plain("*                      *");
    bb.plain("* Pre Configure self ! *");
    bb.plain("*                      *");
    bb.plain("************************");
}
do_configure[nostamp] = "1"
addtask do_configure

do_build[depends] = "printhello:do_configure printbeef:do_configure printbird:do_configure"

python do_build() {
    bb.plain("********************");
    bb.plain("*                  *");
    bb.plain("*  Hello, World!   *");
    bb.plain("*                  *");
    bb.plain("********************");
}

printbird.bb

DESCRIPTION = "Prints Bird Info"
PN = 'printbird'
PV = '1'

python do_configure() {
    bb.plain("************************");
    bb.plain("*                      *");
    bb.plain("* Pre Configure bird ! *");
    bb.plain("*                      *");
    bb.plain("************************");
}

do_configure[nostamp] = "1"
addtask do_configure

printbeef.bb:

DESCRIPTION = "Prints Beef Info"
PN = 'printbeef'
PV = '1'

python do_configure() {
    bb.plain("************************");
    bb.plain("*                      *");
    bb.plain("* Pre Configure Beef ! *");
    bb.plain("*                      *");
    bb.plain("************************");
}

do_configure[nostamp] = "1"
addtask do_configure

运行结果如下：

************************
*                      *
* Pre Configure bird ! *
*                      *
************************
************************
*                      *
* Pre Configure Beef ! *
*                      *
************************
************************
*                      *
* Pre Configure self ! *
*                      *
************************
********************
*                  *
*  Hello, World!   *
*                  *
********************

可见，通过这种方法，我们可以实现前面2.1.1，2.1.2，2.1.3提到的所有依赖定义方法。

2.2 事件

BitBake提供了事件处理函数机制用于在一些特定场景下执行某个指定函数，例如在某个任务失败后触发事件处理函数，然后发送邮件，另外，事件只能定义在菜谱文件或者类文件中，下面是一个事件的例子，在printhello.bb文件中添加如下内容：

addhandler myclass_eventhandler
python myclass_eventhandler() {
    from bb.event import getName
    bb.plain("The name of the Event is %s" % getName(e))
    bb.plain("The file we run for is %s" % d.getVar('FILE'))
}
myclass_eventhandler[eventmask] = "bb.event.RecipeParsed"

在这个例子中，我们使用addhandler将一个python函数定义为事件处理函数，然后通过[eventmask]属性指定了哪些事件可以触发该函数（若不指定，任何事件都将触发该函数），例子中指定了在解析完菜谱后触发myclass_eventhandler函数。另外在这个例子中，e是一个全局变量，指代的是当前发生的事件，通过getName函数我们可以得到该事件的名称。
下面列出了在标准构建过程中，最经常使用的一些事件：